Библиотека для шагового двигателя Arduino v2.1.5

ОБНОВЛЕНИЯ


  • v1.13 – исправлены мелкие баги, оптимизация
  • v1.14 – исправлены ошибки разгона и торможения в KEEP_SPEED
  • v1.15 – оптимизация, исправлены мелкие баги, stop() больше не сбрасывает maxSpeed
  • v2.0 – оптимизация. Ядро шаговика вынесено в отдельный класс Stepper. Добавлены многоосевые планировщики траекторий
  • v2.1 – добавил GyverStepper2, упрощённая и оптимизированная версия GyverStepper
  • v2.1.3 – починил FOLLOW_POS в GStepper, починил RELATIVE в GPlanner2 и исправил багу с рывками
  • v2.1.4 – GPlanner2: исправил рывки, добавил адаптивное перестроение траектории без остановок, чутка оптимизировал вычисления
  • v2.1.5 – возможность менять скорость и ускорение во время работы планировщика (GStepper2, GPlanner, GPlanner2)

ТЕОРИЯ


Для подключения шаговых моторов к Arduino нужно использовать драйверы. Очень дешёвые и популярные моторы 28byj-48-5v часто продаются вместе со своим драйвером (транзисторная сборка ULN2003), подключить можно к любым 4-м пинам Ардуино и использовать.

Для работы с большими шаговиками (типа Nema 17) нужно использовать специализированные драйверы, ниже вы найдёте описания и схемы подключения для A4988, DRV8825 и TMC2208, драйверы такого формата подключаются и работают практически одинаково, т.к. разработаны для CNC шилдов и взаимозаменяемы. У этих драйверов нужно настроить ток при помощи крутилки на плате. Это можно сделать “на глаз”, заставив мотор вращаться и регулируя крутилку. Мотор должен вращаться, но не вибрировать как перфоратор и сильно не нагреваться. Лучше настроить ток по опорному напряжению Vref, у каждого драйвера оно считается по своей формуле (см. картинки ниже). Берём ток своего мотора из описания,  подставляем в формулу вместо current, считаем, и накручиваем полученное напряжение крутилкой. Для измерения опорного напряжения нужно подключить щупы вольтметра к самой крутилке и пину GND.

Главное преимущество дорогущих драйверов TMC – отсутствие шума/свиста/вибраций при работе, так как драйвер своими силами интерполирует сигнал до микрошага 1/256.

БИБЛИОТЕКА


GyverStepper v2.1.5

Производительная библиотека для управления шаговыми моторами с Arduino

  • Поддержка 4х пинового (шаг и полушаг) и STEP-DIR драйверов
  • Автоматическое отключение питания при достижении цели
  • Режимы работы:
    • Вращение с заданной скоростью. Плавный разгон и торможение с ускорением
    • Следование к позиции с ускорением и ограничением скорости
    • Следование к позиции с заданной скоростью (без ускорения)
  • Быстрый алгоритм управления шагами
  • Поддержка “виртуальных” драйверов
  • Встроенный планировщик скорости и траектории для ЧПУ

Совместимость

Совместима со всеми Arduino платформами (используются Arduino-функции)

УСТАНОВКА


  • Библиотеку можно найти и установить через менеджер библиотек по названию GyverStepper в:
    • Arduino IDE (Инструменты/Управлять библиотеками)
    • Arduino IDE v2 (вкладка “Library Manager”)
    • PlatformIO (PIO Home, вкладка “Libraries”)
  • Про ручную установку читай здесь

ДОКУМЕНТАЦИЯ


Аааа почему так много всего?!
Библиотека содержит набор инструментов для разных сценариев работы с шаговыми моторами

  • StepperCore.h [класс Stepper]: ядро всех остальных классов, умеет быстро щёлкать пинами (AVR) и делать один шаг для настроенного типа драйвера. Поддерживает 4 фазы шаг/полушаг, а также step-dir драйверы.
  • GyverStepper.h [класс GStepper]: основная тяжёлая библиотека, много настроек. Движение одного мотора с ускорением к заданной позиции или вращение с заданной скоростью. Не очень оптимальная работа в прерывании таймера.
  • GyverStepper2.h [класс GStepper2]: новая облегченная версия GyverStepper, практически полностью с ней совместима. Более оптимальный целочисленный гибридный алгоритм движения с ускорением, лёгкий вес. Оптимизировано для работы в прерывании таймера.
  • GyverPlanner.h [класс GPlanner]: многоосевой планировщик траектории, движение с ускорением (2 порядок). Остановка в каждой точке. Оптимальная работа в прерывании таймера.
  • GyverPlanner2.h [класс GPlanner2]: многоосевой планировщик траектории, движение с ускорением (2 порядок). Планирование скорости на маршруте, оптимальное движение по точкам. Оптимальная работа в прерывании таймера.

Инициализация


Библиотека поддерживает два типа драйверов:
  • STEPPER2WIRE - специализированный 2-х проводной драйвер для шагового мотора с протоколом STEP-DIR, например A4988, DRV8825, TMC2208 и прочие.
  • STEPPER4WIRE и STEPPER4WIRE_HALF - 4-х проводной драйвер, т.е. полномостовой (например L298N) или транзисторная сборка (например ULN2003).
    • STEPPER4WIRE управляет мотором в полношаговом режиме (выше скорость и момент).
    • STEPPER4WIRE_HALF - в полушаговом (меньше скорость и момент, но больше шагов на оборот и выше точность).
При инициализации указывается тип драйвера, количество шагов на оборот и пины:
  • GStepper< STEPPER2WIRE> stepper(steps, step, dir); // драйвер step-dir
  • GStepper< STEPPER2WIRE> stepper(steps, step, dir, en); // драйвер step-dir + пин enable
  • GStepper< STEPPER4WIRE> stepper(steps, a1, a2, b1, b2); // драйвер 4 пин
  • GStepper< STEPPER4WIRE> stepper(steps, a1, a2, b1, b2, en); // драйвер 4 пин + enable
  • GStepper< STEPPER4WIRE_HALF> stepper(steps, a1, a2, b1, b2); // драйвер 4 пин полушаг
  • GStepper< STEPPER4WIRE_HALF> stepper(steps, a1, a2, b1, b2, en); // драйвер 4 пин полушаг + enable
Где steps - количество шагов на один оборот вала для расчётов с градусами, step, dir, a1, a2, b1, b2 - любые GPIO на МК, en - пин отключения драйвера EN, любой GPIO на МК. Пин en опциональный, можно не указывать. Для 4-х пиновых драйверов: a1 и a2 - первая обмотка (первая фаза), b1 и b2 - вторая обмотка (вторая фаза). При использовании мотора 28byj-48 с родным драйвером нужно поменять крайние пины местами (например, подключаем D2-IN1, D3-IN2, D4-IN3, D5-IN4, но в программе меняем 5 и 2: stepper(2048, 5, 3, 4, 2);, потому что на драйвере фазы выведены через одну, вот картинка). При подключении через мостовой драйвер - подключать и указывать пины по порядку выхода фаз из мотора (см. последнюю схему выше). Количество шагов на оборот нужно для работы функций, которые устанавливают или читают параметр в градусах. Если они не нужны - количество шагов можно поставить любое (единичку). Если нужно - количество шагов нужно указывать с учётом редукторов и микрошагов:
  • Пример 1: есть мотор NEMA 17, он имеет 200 полных шагов на оборот (по документации). Подключен через драйвер с настроенным микрошагом 1/16. При создании объекта библиотеки нужно указать 200*16 шагов.
  • Пример 2: есть мотор 28byj-48-5v, имеет 32 полных шага на оборот и редуктор с соотношением 63.68395:1. Подключен через микросхему ULN2003. Итоговое количество шагов на оборот составляет 63.68395*32 == 2038 для режима полного шага (STEPPER4WIRE).
  • Пример 3: подключим тот же самый мотор 28byj-48-5v, но в режиме полушага (STEPPER4WIRE_HALF). Количество шагов на оборот удвоится (32*2 == 64) и, с учётом редуктора, станет равным 4076.

Время шага [NEW!]


Для драйверов STEP-DIR сделана задержка между переключением состояния пина STEP, эта задержка является минимальной, т.е. она может быть больше, чем нужно, но если будет меньше - возможна нестабильная работа драйвера. По умолчанию она составляет 4 микросекунды, но разным драйверам она нужна разная (для других драйверов см. даташит):
  • A4988 - 1 мкс
  • DRV8825 - 4 мкс
  • TB6500 - 1 мкс
Также увеличение задержки может повысить стабильность работы при использовании длинных неэкранированных проводов от микроконтроллера к драйверу (к пину STEP). Для изменения величины задержки сделай дефайн DRIVER_STEP_TIME перед подключением библиотеки:
#define DRIVER_STEP_TIME 10  // меняем задержку на 10 мкс
#include "GyverStepper.h"

Медленные скорости (new!)


В версии 1.6 скорость во всех режимах может быть задана в виде десятичной дроби (тип float), то есть меньше одного шага в секунду. Минимальная скорость ограничена разрешением используемой в библиотеке micros() и составляет 1 шаг в час. Для удобного задания медленных скоростей появились макросы degPerMinute() и degPerHour(), которые нужно использовать совместно с setSpeedDeg() и setMaxSpeedDeg():
stepper.setMaxSpeedDeg(degPerMinute(360));  // скорость 360 градусов в минуту для режима FOLLOW_POS

Тик и тайминги


Самый главный метод библиотеки - tick(), при активной работе мотора его нужно вызывать как можно чаще. Тик имеет встроенный таймер на micros() и работает по нему. Если в коде программы присутствуют задержки на большее время, чем нужно мотору на текущей скорости, скорость мотора будет ограничена этой задержкой. Узнать минимальный период вызова tick() (при установленной скорости) можно при помощи getMinPeriod(), который вернёт его в микросекундах. Также можно напрямую опрашивать переменную stepTime, в которой хранится текущий период. Эти инструменты можно использовать для организации работы шаговика в прерывании таймера (см. пример timerISR). Также .tick() возвращает true, если мотор движется к цели или крутится по KEEP_SPEED и false, если мотор остановлен или приехал. Метод getState() возвращает текущее состояние мотора аналогично tick().

Смена направления


Можно глобально (для всех режимов) сменить направление вращения мотора при помощи reverse(true).

Режимы работы


Библиотека имеет два режима работы с мотором, устанавливается при помощи setRunMode(mode), где mode:
  • FOLLOW_POS - режим плавного движения к заданной позиции с ускорением и ограничением скорости.
  • KEEP_SPEED - режим вращения с заданной скоростью (знак скорости задаёт направление вращения).

Режим FOLLOW_POS


В этом режиме мотор следует на указанную позицию в шагах или градусах. Для её установки есть следующие методы:
  • setTarget(pos) - установка абсолютной целевой позиции в шагах, принимает положительные и отрицательные значения (тип данных long).
  • setTarget(pos, type) - то же самое, но можно указать тип позиции type - абсолютная ABSOLUTE или относительная RELATIVE.
  • setTargetDeg(pos) - установка абсолютной целевой позиции в градусах, принимает положительные и отрицательные дробные значения (тип данных float).
  • setTargetDeg(pos, type) - то же самое, но можно указать тип позиции type - абсолютная ABSOLUTE или относительная RELATIVE.
Примечание: абсолютная позиция - говоришь мотору повернуться на 300 шагов, он повернётся на позицию 300. При повторном вызове  ничего не произойдёт. Относительная - говоришь повернуться на 300 - он повернётся на 300 относительно текущей позиции. Если вызвать ещё раз через некоторое время - цель сместится относительно текущей позиции вала. Установленную целевую позицию можно прочитать:
  • getTarget() - возвращает тип данных long
  • getTargetDeg() - возвращает тип данных float
Дополнительно можно настроить максимальную скорость и ускорение при движении к целевой позиции:
  • setMaxSpeed(speed) - установка максимальной скорости по модулю в шагах/секунду, тип данных float. По умолчанию 300.
  • setMaxSpeedDeg(speed) - установка максимальной скорости по модулю в градусах/секунду, тип данных float.
  • setAcceleration(accel) - установка ускорения по модулю в шагах/сек/сек, тип данных float. По умолчанию 300.
  • setAccelerationDeg(accel) - установка ускорения по модулю в градусах/сек/сек, тип данных float.
Примечание: при установке ускорения в ноль 0 мотор будет двигаться к позиции с максимальной скоростью, заданной в setMaxSpeed(). Также можно вручную установить текущую позицию мотора в шагах и градусах при помощи:
  • setCurrent(long pos);
  • setCurrentDeg(float pos);
И прочитать её:
  • getCurrent();
  • getCurrentDeg();

Режим KEEP_SPEED


В этом режиме мотор просто крутится с заданной скоростью. Скорость задаётся при помощи
  • setSpeed(speed) - в шагах/секунду, положительные и отрицательные целые значения, тип данных float.
  • setSpeedDeg(speed) - в градусах/секунду, положительные и отрицательные дробные значения, тип данных float.
(New!) Вторым аргументом можно передать включение плавного изменения скорости, по умолчанию стоит false (NO_SMOOTH). Смотри пример accelDeccelButton
  • setSpeed(speed, smooth) - в шагах/секунду, положительные и отрицательные целые значения, тип данных float. smooth - SMOOTH или NO_SMOOTH
  • setSpeedDeg(speed, smooth) - в градусах/секунду, положительные и отрицательные дробные значения, тип данных float. smooth - SMOOTH или NO_SMOOTH
Установленную скорость можно прочитать:
  • getSpeed() - возвращает тип данных float
  • getSpeedDeg() - возвращает тип данных float

Алгоритм планировщика скорости


В библиотеке реализовано два алгоритма планирования скорости для режима плавного движения к позиции с ненулевым ускорением:
  • Мой алгоритм: скорость планируется с фиксированным периодом, что сильно разгружает процессор и позволяет работать на скоростях до 30'000 шагов в секунду (полностью загрузив процессор) без наличия посторонних задержек в коде. Сильная экономия процессорного времени оставляет возможность спокойно выполнять параллельно другой код и управлять несколькими моторами в разных режимах на хороших скоростях, и "ещё останется". Немного "резковат" при торможении. Активен по умолчанию.
  • Модифицированный алгоритм из библиотеки AccelStepper: скорость планируется каждый шаг, что очень сильно нагружает процессор и ограничивает скорость до 7'000 шагов в секунду (полностью загрузив процессор) без наличия посторонних задержек в коде (в оригинальной библиотеке - 5'000 шагов/сек). Разгоняется и тормозит максимально плавно. Для активации нужно прописать дефайн #define SMOOTH_ALGORITHM перед подключением библиотеки в коде (см. пример smoothAlgorithm) или раскомментировать данный дефайн в файле библиотеки GyverStepper.h, находится сразу после описания.

Остановка и сброс


  • stop() - плавная остановка с заданным в setAcceleration() ускорением от текущего положения мотора. Можно вызвать в режиме KEEP_SPEED для плавной остановки вращения! Смотри пример accelDeccelButton
  • brake() - резкая остановка мотора. Если активен autoPower(true) - мотор будет отключен.
  • reset() - brake() + сброс текущей позиции в 0. Удобно для остановки и калибровки начала координат по концевику (смотри пример endSwitch).

Управление питанием


Питанием мотора/драйвера можно управлять вручную при помощи enable() и disable(). Данные методы включают и выключают пин Enable (если он указан при инициализации), а также снимают и возвращают питание на управляющие выводы (для 4х пинового драйвера). Поведением пина EN (если он указан при инициализации) можно управлять при помощи invertEn(true) и invertEn(false). По умолчанию установлено enable(false) переводит пин en в низкое состояние. В библиотеке реализовано автоматическое управление питанием, включается при помощи autoPower(true), по умолчанию оно отключено. В режиме FOLLOW_POS при достижении целевой позиции мотор будет автоматически отключен (будет вызван disable()). При дальнейшей установке новой позиции мотор будет автоматически включен (будет вызван enable()).
// Примечание: далее по тексту под "по умолчанию" имеется в виду "даже если не вызывать функцию"

// Здесь происходит движение мотора, вызывать как можно чаще!
// Имеет встроенный таймер
// Возвращает true, если мотор движется к цели или крутится по KEEP_SPEED
bool tick();

// Возвращает то же самое, что tick, т.е. крутится мотор или нет
bool getState();

// Инвертировать направление мотора - true (по умолч. false)
void reverse(bool dir);

// инвертировать поведение EN пина - true (по умолч. false)
void invertEn(bool rev);

// Установка режима работы, mode:
// FOLLOW_POS - следование к позиции setTarget(...)
// KEEP_SPEED - удержание скорости setSpeed(...)
void setRunMode(GS_runMode mode);

// Установка текущей позиции мотора в шагах и градусах
void setCurrent(long pos);
void setCurrentDeg(float pos);

// Чтение текущей позиции мотора в шагах и градусах
long getCurrent();
float getCurrentDeg();

// установка целевой позиции в шагах и градусах (для режима FOLLOW_POS)
// type - ABSOLUTE или RELATIVE, по умолчанию стоит ABSOLUTE
void setTarget(long pos);
void setTarget(long pos, GS_posType type);
void setTargetDeg(float pos);
void setTargetDeg(float pos, GS_posType type);

// Получение целевой позиции в шагах и градусах
long getTarget();
float getTargetDeg();

// Установка максимальной скорости (по модулю) в шагах/секунду и градусах/секунду (для режима FOLLOW_POS)
// по умолч. 300
void setMaxSpeed(float speed);
void setMaxSpeedDeg(float speed);

// Установка ускорения в шагах и градусах в секунду (для режима FOLLOW_POS).
// При значении 0 ускорение отключается и мотор работает 
// по профилю постоянной максимальной скорости setMaxSpeed().
// По умолч. 300
void setAcceleration(int accel);
void setAccelerationDeg(float accel);

// Автоотключение EN при достижении позиции - true (по умолч. false)
void autoPower(bool mode);

// Плавная остановка с заданным ускорением
void stop();

// Жёсткая остановка
void brake();

// Жёсткая остановка + сброс позиции в 0 (для концевиков)
void reset();

// Установка целевой скорости в шагах/секунду и градусах/секунду (для режима KEEP_SPEED)
void setSpeed(float speed);
void setSpeedDeg(float speed);

// Получение целевой скорости в шагах/секунду и градусах/секунду (для режима KEEP_SPEED)
float getSpeed();
float getSpeedDeg();

// Включить мотор (пин EN)
void enable();

// Выключить мотор (пин EN)
void disable();

// Возвращает минимальный период тика мотора в микросекундах при настроенной setMaxSpeed() скорости.
// Можно использовать для настройки прерываний таймера, в обработчике которого будет лежать tick() (см. пример timerISR)
uint16_t getMinPeriod();

// Текущий период "тика" для отладки и всего такого
uint16_t stepTime;

GStepper2, GPlanner и GPlanner2 являются нововведениями в библиотеке и работают чуть иначе, больше ориентированы на движение от точки к точке.

Изменение скорости/ускорения

Скорость и ускорение можно задать в любое время, они будут применены после остановки мотора в конечной точке!

Тикер

Движение мотора происходит внутри tick(), который нужно вызывать как можно чаще, например в loop() (или yield(), если в коде есть delay()) tick() имеет встроенный таймер на micros() и крутит мотор с нужной скоростью.

Также есть не имеющий таймера tickManual(), который делает шаг, считает период и проверяет, не доехал ли мотор до цели. Его нужно вызывать с периодом, который можно получить из getPeriod() в микросекундах. Конструкция для работы в прерывании таймера может выглядеть так:

  if (stepper.tickManual()) setPeriod(stepper.getPeriod());
  else stopTimer();

Пока мотор крутится - таймер перезапускается на новый период, как только мотор приехал - останавливаем таймер.

Режим постоянной скорости

Для запуска режима вращения с постоянной скоростью достаточно вызвать setSpeed(скорость)/setSpeedDeg(скорость). Скорость может быть отрицательной. Остановить мотор можно при помощи brake(). В данной реализации скорость не меняется плавно, то есть включается сразу на заданную и тормозится в 0 при остановке. В реальном применении этого достаточно для движения к концевику (см. пример homing для всех трёх классов).

Режим движения к позиции

При помощи setMaxSpeed()/setMaxSpeedDeg() задаётся максимальная скорость, которой может достигнуть мотор (суммарная квадратичная скорость по осям для GPlanner) во время движения к следующей точке. Эта настройка не имеет отношения к режиму вращения.

При помощи setAcceleration() можно задать ускорение в шагах/секунду^2, с  которым будет меняться скорость. Если поставить ускорение 0 - мотор будет двигаться без ускорения, т.е. сразу с максимальной скоростью.

Для старта движения к позиции достаточно вызвать setTarget(позиция)/setTargetDeg(позиция) (кроме GPlanner2). После выполнения этой функции можно запросить у getPeriod() время до следующего тика и запустить таймер, если мотор работает в прерывании.

Если мотор находится в активном режиме движения к позиции и доезжает до цели - функция ready() однократно вернёт true. В примерах к библиотеке по этому условию "загружается" следующая точка траектории.

Во время движения к позиции можно остановиться:

  • brake() - резко остановит мотор
  • stop() - плавно остановит мотор с заданным ускорением
  • pause() - мотор доедет до заданной позиции, но ready() не вернёт true

Для возобновления движения можно вызвать resume(), траектория мотора будет пересчитана и он двинется к последней заданной в setTarget() позиции.

Текущую позицию мотора (моторов, для GPlanner) можно прочитать как getCurrent(), установить через setCurrent(), а также сбросить в 0 через reset().

GPlanner2 работает чуть иначе, так как содержит буфер траектории. Подробнее о нём читайте ниже

Инициализация

Такая же как в GStepper

GStepper2< STEPPER2WIRE> stepper(шаговНаОборот, step, dir);                          // драйвер step-dir
GStepper2< STEPPER2WIRE> stepper(шаговНаОборот, step, dir, en);                      // драйвер step-dir + пин enable
GStepper2< STEPPER4WIRE> stepper(шаговНаОборот, pin1, pin2, pin3, pin4);             // драйвер 4 пин
GStepper2< STEPPER4WIRE> stepper(шаговНаОборот, pin1, pin2, pin3, pin4, en);         // драйвер 4 пин + enable
GStepper2< STEPPER4WIRE_HALF> stepper(шаговНаОборот, pin1, pin2, pin3, pin4);        // драйвер 4 пин полушаг
GStepper2< STEPPER4WIRE_HALF> stepper(шаговНаОборот, pin1, pin2, pin3, pin4, en);    // драйвер 4 пин полушаг + enable

GStepper2< STEPPER2WIRE, STEPPER_VIRTUAL> stepper;    // виртуальный драйвер step-dir
GStepper2< STEPPER4WIRE, STEPPER_VIRTUAL> stepper;    // виртуальный драйвер 4 пин

Список функций

// === наследуется из Stepper ====
// настроить пины
void setPins(uint8_t pin1 = 255, uint8_t pin2 = 255, uint8_t pin3 = 255, uint8_t pin4 = 255, uint8_t pin5 = 255);

void step();                                // сделать шаг
void invertEn(bool val);                    // инвертировать поведение EN пина
void reverse(bool val);                     // инвертировать направление мотора
void disable();                             // отключить питание и EN
void enable();                              // включить питание и EN
void attachStep(void (*handler)(uint8_t));  // подключить обработчик шага
void attachPower(void (*handler)(bool));    // подключить обработчик питания

int32_t pos;                                // текущая позиция в шагах
int8_t dir;                                 // направление (1, -1)

// ========= GStepper2 ==========
// тикер
bool tick();                                // тикер движения, вызывать часто. Вернёт true, если мотор движется
bool tickManual();                          // ручной тикер для вызова в прерывании таймера с периодом getPeriod(). Вернёт true, если мотор движется
bool ready();                               // однократно вернёт true, если мотор доехал до установленной позиции и остановился

// вращение
void setSpeed(int16_t speed);               // установить скорость в шагах/сек и запустить вращение
void setSpeed(float speed);                 // установить скорость в шагах/сек (float) и запустить вращение

// движение к цели
void setTarget(int32_t ntar, GS_posType type = ABSOLUTE);       // установить цель в шагах и опционально режим ABSOLUTE/RELATIVE
void setTargetDeg(int32_t ntar, GS_posType type = ABSOLUTE);    // установить цель в градусах и опционально режим ABSOLUTE/RELATIVE
int32_t getTarget();                                            // получить целевую позицию в шагах

void setAcceleration(uint16_t nA);          // установка ускорения в шаг/сек^2
void setMaxSpeed(int speed);                // установить скорость движения при следовании к позиции setTarget() в шагах/сек
void setMaxSpeed(float speed);              // установить скорость движения при следовании к позиции setTarget() в шагах/сек, float
void setMaxSpeedDeg(int speed);             // установить скорость движения при следовании к позиции в град/сек
void setMaxSpeedDeg(float speed);           // установить скорость движения при следовании к позиции в град/сек, float

void setCurrent(int32_t npos);              // установить текущую позицию
int32_t getCurrent();                       // получить текущую позицию
void reset();                               // сбросить текущую позицию в 0

// всякое
uint32_t getPeriod();                       // получить текущий период тиков
void brake();                               // резко остановить мотор
void pause();                               // пауза - доехать до заданной точки и ждать (ready() не вернёт true, пока ты на паузе)
void resume();                              // продолжить движение после остановки/паузы
uint8_t getStatus();                        // текущий статус: 0 - стоим, 1 - едем, 2 - едем к точке паузы, 3 - крутимся со скоростью, 4 - тормозим

// ===== ДЕФАЙНЫ НАСТРОЕК =====
// дефайнить перед подключением библиотеки
#define GS_NO_ACCEL                         // отключить модуль движения с ускорением (уменьшить вес кода)

"Слежение" не реализовано!

В обычной GyverStepper мотор ведёт себя как инертный объект, позволяя менять конечную точку траектории прямо во время движения: профиль скорости будет пересчитан и мотор без резких движений изменит траекторию. В GStepper2 это не работает! При изменении цели во время движения мотор будет остановлен и только после этого отправлен на новую точку.

Пример

// крутим туда сюда, тикаем в loop

#include "GyverStepper2.h"
GStepper2< STEPPER2WIRE> stepper(400, 2, 3);

void setup() {
  Serial.begin(9600);
  //stepper.enable();
  stepper.setMaxSpeed(100);     // скорость движения к цели
  stepper.setAcceleration(200); // ускорение
  stepper.setTarget(300);       // цель
}

bool dir = 1;
void loop() {
  stepper.tick();   // мотор асинхронно крутится тут

  // если приехали
  if (stepper.ready()) {
    dir = !dir;   // разворачиваем
    stepper.setTarget(dir * 300); // едем в другую сторону
  }

  // асинхронный вывод в порт
  static uint32_t tmr;
  if (millis() - tmr >= 30) {
    tmr = millis();
    Serial.println(stepper.pos);
  }
}

Многоосевой планировщик траекторий для шаговых моторов и создания станка с ЧПУ

  • ОСТАНОВКА В КАЖДОЙ ТОЧКЕ. БУФЕР НА ОДНУ СЛЕДУЮЩУЮ ПОЗИЦИЮ
  • Макс. скорость: 37000 шаг/с на полной, 14000 шаг/с на разгоне
  • Трапецеидальный профиль скорости (планировщик 2-го порядка)
  • Настройка скорости и ускорения
  • Любое количество осей. Будут двигаться синхронно к заданным целям
  • Быстрая целочисленная модель планирования траектории и скорости
  • Режим постоянного вращения для одной оси (для движения к концевику например)
  • Тормоз/плавная остановка/пауза на траектории планировщика
  • Оптимизировано для работы по прерыванию таймера
  • Быстрый контроль пинов шаговика для Arduino AVR

Как работает

Планировщик управляет любым количеством моторов, вращая их к указанной позиции. В данной версии остановка происходит в каждой точке траектории, после чего поднимается флаг ready() и ожидает установки следующей точки.

Инициализация

GPlanner< драйвер, количество осей> planner;

Использование

void addStepper(uint8_t axis, Stepper &stp);    // подключить мотор класса Stepper на ось axis
// примечание: тип драйвера должен совпадать у планировщика и моторов

// НАСТРОЙКИ
void setMaxSpeed(float nV);                 // установка максимальной скорости планировщика в шаг/сек
void setAcceleration(uint16_t nA);          // установка ускорения планировщика в шаг/сек^2

// ПЛАНИРОВЩИК
uint32_t getPeriod();                       // возвращает время в мкс до следующего вызова tick/tickManual
bool ready();                               // true - готов принять следующую точку маршрута
void pause();                               // пауза (доехать до заданной точки и ждать). ready() не вернёт true, пока ты на паузе
void stop();                                // остановить плавно (с заданным ускорением)
void brake();                               // резко остановить моторы из любого режима
void resume();                              // продолжить после остановки/паузы
void reset();                               // сбросить счётчики всех моторов в 0
uint8_t getStatus();                        // текущий статус: 0 - стоим, 1 - едем, 2 - едем к точке паузы, 3 -крутимся со скоростью 

// СКОРОСТЬ
void setSpeed(uint8_t axis, float speed);   // режим постоянного вращения для оси axis со скоростью speed шаг/сек (м.б. отрицателеьной)

// ПОЗИЦИЯ
void setCurrent(int16_t cur[]);             // установить текущее положение моторов
void setCurrent(int32_t cur[]);             // установить текущее положение моторов
int32_t getCurrent(int axis);               // получить текущую позицию по оси axis

// установить цель в шагах и начать движение. type - ABSOLUTE (по умолч.) или RELATIVE
// ABSOLUTE - конкретные координаты точки, куда двигаться
// RELATIVE - смещение относительно текущих положений моторов
// вернёт true, если цель установлена. false, если цель совпадает с текущей
bool setTarget(int32_t target[]);
bool setTarget(int16_t target[]);
bool setTarget(int32_t target[], type);
bool setTarget(int16_t target[], type);
int32_t getTarget(int axis);                // получить цель в шагах на оси axis

// ТИКЕР
// тикер, вызывать как можно чаще. Вернёт true, если мотор крутится
// здесь делаются шаги как для движения по точкам, так и для вращения по скорости
bool tick();

// ручной тикер для вызова в прерывании или где то ещё. Выполняется 20..50 us
bool tickManual();

Пример

// базовый пример: как создать и запустить планировщик
// при запуске моторы будут отправлены на первую позицию
// при достижении - на вторую. После этого движение прекратится
// открой плоттер и смотри графики

#include "GyverPlanner.h"
// создаём моторы класса Stepper с указанием типа драйвера и пинов
// МОТОРЫ ДОЛЖНЫ БЫТЬ С ОДИНАКОВЫМ ТИПОМ ДРАЙВЕРА
// вот они красавцы
Stepper< STEPPER2WIRE > stepper1(2, 3);
Stepper< STEPPER2WIRE > stepper2(4, 5);

// создаём планировщик, указываем в <> тип драйвера КАК У МОТОРОВ
// и количество осей, равное количеству моторов (любое больше 1)
GPlanner< STEPPER2WIRE, 2 > planner;

void setup() {
  Serial.begin(115200);
  // добавляем шаговики на оси
  planner.addStepper(0, stepper1);  // ось 0
  planner.addStepper(1, stepper2);  // ось 1

  // устанавливаем ускорение и скорость
  planner.setAcceleration(100);
  planner.setMaxSpeed(300);

  planner.reset();  // сбрасываем все позиции в 0 (они и так в 0 при запуске)

  // массив с целевыми позициями осей, размер массива равен количеству осей
  int target[] = {300, 200};

  // отправляем
  planner.setTarget(target);
}

void loop() {
  // здесь происходит движение моторов, вызывать как можно чаще
  planner.tick();

  // вернёт true, если все моторы доехали
  if (planner.ready()) {
    // загружаем новую точку
    int newTarget[] = {10, 50};
    planner.setTarget(newTarget);
  }

  // асинхронно вывожу в порт графики
  static uint32_t tmr;
  if (millis() - tmr >= 20) {
    tmr = millis();
    Serial.print(stepper1.pos);
    Serial.print(',');
    Serial.println(stepper2.pos);
  }
}

Многоосевой планировщик траекторий для шаговых моторов и создания станка с ЧПУ

  • ПЛАНИРОВАНИЕ СКОРОСТИ НА МАРШРУТЕ. НАСТРАИВАЕМЫЙ БУФЕР
  • Макс. скорость: 37000 шаг/с на полной, 14000 шаг/с на разгоне
  • Трапецеидальный профиль скорости (планировщик 2-го порядка)
  • Настройка скорости и ускорения
  • Любое количество осей. Будут двигаться синхронно к заданным целям
  • Быстрая целочисленная модель планирования траектории и скорости
  • Режим постоянного вращения для одной оси (для движения к концевику например)
  • Тормоз/плавная остановка/пауза на траектории планировщика
  • Оптимизировано для работы по прерыванию таймера
  • Быстрый контроль пинов шаговика для Arduino AVR

Как работает

Планировщик управляет любым количеством моторов, вращая их к указанной позиции. В данной версии реализован буфер траектории, который можно наполнять точками, пока available() возвращает true. addTarget() принимает:

  • Массив точек указанного при инициализации размера
  • Флаг остановки. Если передать 1 - планировщик остановит мотор в этой точке и будет ждать дальнейшей команды resume()
  • Тип точки: ABSOLUTE (абсолютная координата) или RELATIVE (относительно предыдущей точки)

Когда планировщик приезжает до точки остановки - он встаёт на паузу (например для включения выключения инструмента), после совершения нужных действий вызываем resume() и он продолжает движение.
В отличие от предыдущего GPlanner, в GPlanner2 реализован просчёт траектории в буфере и планирование скорости для всех точек, что позволяет системе двигаться быстрее и не тормозить в каждой точке.

Инициализация

GPlanner2< драйвер, количество осей > planner;                 // объявление
GPlanner2< драйвер, количество осей, размер буфера > planner;  // + размер буфера (по умолч. 32)

Использование

void addStepper(uint8_t axis, Stepper &stp);    // подключить мотор класса Stepper на ось axis
// примечание: тип драйвера должен совпадать у планировщика и моторов

// НАСТРОЙКИ
void setMaxSpeed(float nV);                 // установка максимальной скорости планировщика в шаг/сек
void setAcceleration(uint16_t nA);          // установка ускорения планировщика в шаг/сек^2
void setDtA(float newDta);                  // установить dt смены скорости в повороте, 0.0.. 1.0 по умолч. 0.3

// ПЛАНИРОВЩИК
uint32_t getPeriod();                       // возвращает время в мкс до следующего вызова tick/tickManual
void start();                               // начать работу
void stop();                                // остановить плавно (с заданным ускорением)
void brake();                               // резко остановить моторы из любого режима
void resume();                              // продолжить после остановки или конечной точки маршрута
void reset();                               // сбросить счётчики всех моторов в 0
bool ready();                               // флаг достижения точки остановки. После неё нужно вызывать resume
bool available();                           // true - в буфере планировщика есть место под новю точку

uint8_t getStatus();                        // текущий статус:
// 0 ожидание команды (остановлен)
// 1 ожидание буфера
// 2 в пути
// 3 на паузу
// 4 на стоп
// 5 крутится setSpeed

// СКОРОСТЬ
void setSpeed(uint8_t axis, float speed);   // режим постоянного вращения для оси axis со скоростью speed шаг/сек (м.б. отрицательной)

// ПОЗИЦИЯ
// добавить новую точку маршрута. Массив координат, флаг окончания и абсолютный/относительный
void addTarget(int32_t tar[], uint8_t l, GS_posType type = ABSOLUTE);
void addTarget(int16_t tar[], uint8_t l, GS_posType type = ABSOLUTE);
// ABSOLUTE - конкретные координаты точки, куда двигаться
// RELATIVE - смещение относительно текущих положений моторов

void setCurrent(int16_t cur[]);             // установить текущее положение моторов
void setCurrent(int32_t cur[]);             // установить текущее положение моторов
int32_t getCurrent(int axis);               // получить текущую позицию по оси axis
int32_t getTarget(int axis);                // получить текущую цель в шагах на оси axis

// ТИКЕР
// тикер, вызывать как можно чаще. Вернёт true, если мотор крутится
// здесь делаются шаги для движения по точкам, для вращения по скорости, а также перестройка буфера
bool tick();

// ручной тикер для вызова в прерывании или где то ещё. Выполняется 20..50 us
bool tickManual();

// обработчик буфера. Сам вызывается в tick. Нужно вызывать вручную при работе с tickManual
// вернёт true, если планировщик отправил моторы на новую позицию (в этот момент можно запускать таймер)
void checkBuffer();

Пример

// пример с записанным в памяти маршрутом
// смотри график, а лучше запусти stepperPlot

int path[][2] = {
  {100, 250},
  {160, 30},
  {230, 250},
  {60, 100},
  {270, 100},
};

// количество точек (пусть компилятор сам считает)
// как вес всего массива / (2+2) байта
int nodeAmount = sizeof(path) / 4;

#include "GyverPlanner2.h"
Stepper< STEPPER2WIRE > stepper1(2, 3);
Stepper< STEPPER2WIRE > stepper2(4, 5);
GPlanner2< STEPPER2WIRE, 2 > planner;

void setup() {
  Serial.begin(115200);
  // добавляем шаговики на оси
  planner.addStepper(0, stepper1);  // ось 0
  planner.addStepper(1, stepper2);  // ось 1

  // устанавливаем ускорение и скорость
  planner.setAcceleration(500);
  planner.setMaxSpeed(500);

  // начальная точка системы должна совпадать с первой точкой маршрута
  planner.setCurrent(path[0]);
  planner.start();
}

int count = 0;  // счётчик точек маршрута
void loop() {
  // здесь происходит движение моторов, вызывать как можно чаще
  planner.tick();

  // если в буфере планировщика есть место
  if (planner.available()) {
    // добавляем точку маршрута и является ли она точкой остановки (0 - нет)
    planner.addTarget(path[count], 0);
    if (++count >= sizeof(path) / 4) count = 0; // закольцевать
  }

  // асинхронно вывожу в порт графики
  static uint32_t tmr;
  if (millis() - tmr >= 20) {
    tmr = millis();
    Serial.print(stepper1.pos);
    Serial.print(',');
    Serial.println(stepper2.pos);
  }
}

ПРИМЕРЫ


Это некоторые примеры к GyverStepper. Остальные примеры, а также примеры работы с планировщиком траектории смотри в папке examples библиотеки. Можно открыть из Arduino IDE/Файл/Примеры , открыть вручную или посмотреть на гитхабе в браузере

// демо - основные возможности библиотеки

#include <GyverStepper.h>
GStepper<STEPPER4WIRE> stepper(2048, 5, 3, 4, 2);
// мотор с драйвером ULN2003 подключается по порядку пинов, но крайние нужно поменять местами
// то есть у меня подключено D2-IN1, D3-IN2, D4-IN3, D5-IN4, но в программе поменял 5 и 2

// создание объекта
// steps - шагов на один оборот вала (для расчётов с градусами)
// step, dir, pin1, pin2, pin3, pin4 - любые GPIO
// en - пин отключения драйвера, любой GPIO
//GStepper<STEPPER2WIRE> stepper(steps, step, dir);                   // драйвер step-dir
//GStepper<STEPPER2WIRE> stepper(steps, step, dir, en);               // драйвер step-dir + пин enable
//GStepper<STEPPER4WIRE> stepper(steps, pin1, pin2, pin3, pin4);      // драйвер 4 пин
//GStepper<STEPPER4WIRE> stepper(steps, pin1, pin2, pin3, pin4, en);  // драйвер 4 пин + enable
//GStepper<STEPPER4WIRE_HALF> stepper(steps, pin1, pin2, pin3, pin4);     // драйвер 4 пин полушаг
//GStepper<STEPPER4WIRE_HALF> stepper(steps, pin1, pin2, pin3, pin4, en); // драйвер 4 пин полушаг + enable

void setup() {
  Serial.begin(115200);
  // режим поддержания скорости
  stepper.setRunMode(KEEP_SPEED);

  // можно установить скорость
  stepper.setSpeed(120);    // в шагах/сек
  stepper.setSpeedDeg(80);  // в градусах/сек

  // режим следования к целевй позиции
  stepper.setRunMode(FOLLOW_POS);

  // можно установить позицию
  stepper.setTarget(-2024);    // в шагах
  stepper.setTargetDeg(-360);  // в градусах

  // установка макс. скорости в градусах/сек
  stepper.setMaxSpeedDeg(400);
  
  // установка макс. скорости в шагах/сек
  stepper.setMaxSpeed(400);

  // установка ускорения в градусах/сек/сек
  stepper.setAccelerationDeg(300);

  // установка ускорения в шагах/сек/сек
  stepper.setAcceleration(300);

  // отключать мотор при достижении цели
  stepper.autoPower(true);

  // включить мотор (если указан пин en)
  stepper.enable();
}

void loop() {
  // просто крутим туды-сюды
  if (!stepper.tick()) {
    static bool dir;
    dir = !dir;
    stepper.setTarget(dir ? -1024 : 1024);
  }
}
// пример с использованием "внешнего" драйвера, который может быть
// подключен к расширителю портов.

// в качестве примера использую digitalWrite и родные пины
#define PIN_A 2
#define PIN_B 4
#define PIN_C 3
#define PIN_D 5

#include <GyverStepper.h>
GStepper<STEPPER4WIRE, STEPPER_VIRTUAL> stepper(2048);

void setup() {
  Serial.begin(9600);
  // выходы
  pinMode(PIN_A, 1);
  pinMode(PIN_B, 1);
  pinMode(PIN_C, 1);
  pinMode(PIN_D, 1);
  
  stepper.setRunMode(KEEP_SPEED); // режим поддержания скорости
  stepper.setSpeedDeg(100);       // в градусах/сек
  stepper.setAcceleration(500);

  // подключить свою функцию-обработчик шага
  stepper.attachStep(step);
  
  // подключить свою функцию-обработчик для управления питанием
  stepper.attachPower(pwr);

  stepper.autoPower(1);   // включаем авто выкл питания
}

// наша функция-обработчик. Будет вызываться на каждом шагу
// у STEPPER4WIRE val содержит состояния обмоток как 0bABCD
// у STEPPER2WIRE val содержит 0 или 1 как DIR, STEP нужно дёрнуть самому
void step(byte val) {
  // дёргаем вручную пины
  digitalWrite(PIN_D, val & 1);
  val >>= 1;
  digitalWrite(PIN_C, val & 1);
  val >>= 1;
  digitalWrite(PIN_B, val & 1);
  val >>= 1;
  digitalWrite(PIN_A, val & 1);
}

void pwr(bool val) {
  // тут val будет 0 или 1 в зависимости от питания. Подавай на EN
  Serial.println(val);
}

void loop() {
  stepper.tick();

  // разгон и остановка каждые 3 секунды
  static uint32_t tmr;
  if (millis() - tmr >= 3000) {
    tmr = millis();
    static bool dir = 1;
    dir = !dir;
    if (!dir) stepper.stop();
    else stepper.setSpeedDeg(100);
  }
}

// крутим мотор туда-сюда плавно с ускорением

#include <GyverStepper.h>
GStepper<STEPPER4WIRE> stepper(2048, 5, 3, 4, 2);
// мотор с драйвером ULN2003 подключается по порядку пинов, но крайние нужно поменять местами
// то есть у меня подключено D2-IN1, D3-IN2, D4-IN3, D5-IN4, но в программе поменял 5 и 2

void setup() {
  Serial.begin(115200);

  // режим следования к целевй позиции
  stepper.setRunMode(FOLLOW_POS);

  // установка макс. скорости в шагах/сек
  stepper.setMaxSpeed(400);

  // установка ускорения в шагах/сек/сек
  stepper.setAcceleration(500);
}

void loop() {
  // просто крутим туды-сюды
  if (!stepper.tick()) {
    static bool dir;
    dir = !dir;
    stepper.setTarget(dir ? -400 : 400);
  }

  // график положения
  static uint32_t tmr2;
  if (millis() - tmr2 > 20) {
    tmr2 = millis();
    Serial.println(stepper.getCurrent());
  }
}
// управляем скоростью из СОМ порта
// отправь q для тормоза
// отправь w для плавной остановки
// отправь e для скорости 5 град/сек
// отправь r для скорости 100 град/сек

#include <GyverStepper.h>
GStepper<STEPPER4WIRE> stepper(2048, 5, 3, 4, 2);

void setup() {
  Serial.begin(9600);
  stepper.setRunMode(KEEP_SPEED); // режим поддержания скорости
  stepper.setSpeedDeg(5);         // в градусах/сек
}

void loop() {
  stepper.tick();
  if (Serial.available()) {
    char ch = Serial.read();
    if (ch == 'q') stepper.brake();
    if (ch == 'w') stepper.stop();
    if (ch == 'e') stepper.setSpeedDeg(5);
    if (ch == 'r') stepper.setSpeedDeg(100);
  }
}
// крутим мотор туда-сюда плавно с ускорением
// для синхронного многоосевого движения используй встроенный планировщик траекторий
// папка с примерами Planner и Planner2

#include "GyverStepper.h"
// подключим три мотора
// у первого и второго управление EN не подключаем
GStepper stepper1(100, 2, 3);
GStepper stepper2(100, 4, 5);
GStepper stepper3(100, 6, 7, 8);

void setup() {
  // мотор 1 просто вращается
  stepper1.setRunMode(KEEP_SPEED);
  stepper1.setSpeed(300);

  // мотор 2 будет делать sweep по проверке tick
  stepper2.setRunMode(FOLLOW_POS);
  stepper2.setMaxSpeed(1000);
  stepper2.setAcceleration(300);

  // мотор 3 будет перемещаться на случайную позицию
  stepper3.setRunMode(FOLLOW_POS);
  stepper3.setMaxSpeed(1000);
  stepper3.setAcceleration(300);
  stepper3.autoPower(true);
  stepper3.enable();
}

void loop() {
  // первый мотор
  stepper1.tick();
  
  // второй крутим туды-сюды (-1000, 1000)
  if (!stepper2.tick()) {
    static bool dir;
    dir = !dir;
    stepper2.setTarget(dir ? -1000 : 1000);
  }

  // третий по таймеру
  // будет отключаться при остановке
  stepper3.tick();
  static uint32_t tmr;
  if (millis() - tmr > 5000) {   // каждые 5 секунд
    tmr = millis();
    stepper3.setTarget(random(0, 2000));  // рандом 0-2000
  }
}

ПОДДЕРЖАТЬ


Вы можете поддержать меня за создание доступных проектов с открытым исходным кодом, полный список реквизитов есть вот здесь.

Подписаться
Уведомить о
guest
88 комментариев
Старые
Новые Популярные
Межтекстовые Отзывы
Посмотреть все комментарии