PID РЕГУЛЯТОР НА ARDUINO

ПИД регулятор – мощный инструмент, позволяющий удерживать заданную величину (температура, скорость вала, положение) при помощи управляющего устройства (обогреватель, контроллер мотора, линейный привод). Вот отличная статья по теории, что такое ПИД регулятор, как он работает и как его настроить. А я предлагаю свою библиотеку для работы с PID на Arduino.

ПИД регулятор выдаёт на  выходе сигнал для плавного управления управляющим устройством (диммер, транзистор), если вам нужно реле – используйте библиотеку GyverRelay.

Алгоритм ПИД регулятора выглядит так, можете использовать его напрямую в скетче:

// ГЛОБАЛЬНЫЕ ПЕРЕМЕННЫЕ
// величины регулятора
int setpoint = 0;   // заданная величина, которую должен поддерживать регулятор
int input = 0;      // сигнал с датчика (например температура, которую мы регулируем)
int output = 0;     // выход с регулятора на управляющее устройство (например величина ШИМ или угол поворота серво)
int pidMin = 0;     // минимальный выход с регулятора
int pidMax = 255;   // максимальный выход с регулятора

// коэффициенты
float Kp = 1.0;
float Ki = 1.0;
float Kd = 1.0;
float _dt_s = 0.1; // время итерации в секундах

// вспомогательные переменные
int prevInput = 0;
float integral = 0.0;

// ПИД
// функция расчёта выходного сигнала
int computePID() {
  float error = setpoint - input;           // ошибка регулирования
  float delta_input = prevInput - input;    // изменение входного сигнала
  prevInput = input;
  output = 0;
  output += (float)error * Kp;                  // пропорционально ошибке регулирования
  output += (float)delta_input * Kd / _dt_s;    // дифференциальная составляющая
  integral += (float)error * Ki * _dt_s;        // расчёт интегральной составляющей
  // тут можно ограничить интегральную составляющую!
  output += integral;                           // прибавляем интегральную составляющую
  output = constrain(output, pidMin, pidMax);   // ограничиваем выход
  return output;
}

БИБЛИОТЕКА GYVERPID

Библиотека классического PID регулятора для Arduino

  • Быстрая и лёгкая библиотека
  • Время одного расчёта около 70 мкс
  • Режим работы по величине или по её изменению (для интегрирующих процессов)
  • На выбор целочисленная или float модель вычисления
  • Возвращает результат по встроенному таймеру или в ручном режиме

Поддерживаемые платформы: все Arduino (используются стандартные Wiring-функции)

Версия 1.1 – убраны дефайны
Версия 1.2 – возвращены дефайны
Версия 1.3 – вычисления ускорены, библиотека облегчена
Версия 2.0 – логика работы чуть переосмыслена, код улучшен, упрощён и облегчён
Версия 2.1 – integral вынесен в public
Версия 2.2 – оптимизация вычислений
Версия 2.3 – добавлен режим PID_INTEGRAL_WINDOW
Версия 2.4 – реализация внесена в класс
Версия 3.0
– Добавлен режим оптимизации интегральной составляющей (см. доку)
– Добавлены автоматические калибровщики коэффициентов (см. примеры и доку)
Версия 3.1 – исправлен режиме ON_RATE, добавлено автоограничение инт. суммы

ДОКУМЕНТАЦИЯ


Логика работы

ПИД регулятор принимает на вход две величины:

  • Входной сигнал input – сигнал с датчика: температура, скорость, положение, и т.д;
  • Установку setpoint – величина, к которой регулятор будет стараться регулировать входной сигнал (температуру, скорость, положение…)

С ПИД регулятора выходит выходной (управляющий) сигнал output – безразмерная величина, которая подаётся на управляющее устройство. Это может быть транзистор с ШИМ сигналом, диммер, сервопривод, и т.д. Выходной сигнал должен влиять на входной сигнал: нагреватель нагревает объект с датчиком температуры, мотор крутится и даёт значения для датчика оборотов, и т.д.

Закон управления регулятора устанавливается при помощи коэффициентов Kp, Ki и Kd.

  • Kp – пропорциональный коэффициент, выходная величина будет увеличиваться пропорционально разнице входного сигнала и установки.
  • Ki – коэффициент интегрирующей составляющей, отвечает за накапливающуюся ошибку, позволяет сгладить пульсации и нивелировать маленькую ошибку.
  • Kd – коэффициент дифференциальной составляющей, отвечает за скорость изменения величины, позволяет уменьшить раскачку системы.

Инициализация

Можно инициализировать объект тремя способами:

  • GyverPID regulator;  // инициализировать без настроек (всё по нулям, dt 100 мс)
  • GyverPID regulator(kp, ki, kd);// инициализировать с коэффициентами. dt будет стандартно 100 мс
  • GyverPID regulator(kp, ki, kd, dt);   // инициализировать с коэффициентами и dt (в миллисекундах)

Режимы и настройки

Направление регулирования: зависит от того, в какую сторону направляется управляемая величина input при увеличении управляющего сигнала output. Например: охлаждение или нагрев, разгон или торможение, и т.д. По умолчанию стоит NORMAL – регулятор считает, что увеличение управляющего сигнала output увеличит входной сигнал input. Устанавливается командой

setDirection(dir);  // dirNORMAL или REVERSE

Режим работы: режим регулирования по ошибке входного сигнала ON_ERROR или по изменению входного сигнала ON_RATE. По умолчанию стоит ON_ERROR, его рекомендуется использовать в большинстве случаев, потому что большинство процессов – самоустанавливающиеся (температура нагревателя сама установится в своём максимуме, скорость мотора – тоже). Режим ON_RATE рекомендуется использовать в интегрирующих процессах, в которых выходная величина влияет на скорость изменения входной величины, например положение моторизированного слайдера, который не остановится при управляющем сигнале, отличном от нуля. Таким процессом будет проще управлять в режиме ON_RATE. Устанавливается командой

setMode(mode); // modeON_ERROR или ON_RATE

Подробнее про этот режим смотри в самом конце документации, в разделе оптимизации интегральной суммы.

Пределы выхода: ограничение значения выходного сигнала, по умолчанию: 0-255 (для 8 бит ШИМ). Может быть установлено 0-180 для угла сервопривода, и т.д. Устанавливается командой

setLimits(min, max);  // установить пределы

Время итерации: время итерации можно изменить в процессе работы (не знаю, зачем, но возможность есть). Время устанавливается в миллисекундах и влияет на функцию getResultTimer(), которая с этим периодом делает новый расчёт управляющего сигнала. Также это время входит в расчёт управляющего сигнала (в И и Д составляющей). Устанавливается командой

setDt(dt);  // установка времени итерации в мс

Установка/чтение параметров

Основные величины регулятора можно менять в любом месте программы любым удобным способом (кнопки, энкодер, передача через UART/GSM/WiFi, как угодно). Коэффициенты регулятора Kp, Ki и Kd можно устанавливать и читать напрямую как члены класса, например

regulator.Kp = 1.5;        // установить
regulator.Ki += 0.7;       // изменить
lcd.print(regulator.Kd);   // читать

Время итерации меняется при помощи метода setDt() (см. выше).

Величины регулятора (вход, установка, выход) также являются членами класса и к ним можно обратиться напрямую для чтения и записи:

regulator.input = 10;     // ВХОД регулятора, например текущая температура
regulator.setpoint = 20;  // УСТАНОВКА регулятора, например необходимая температура
analogWrite(regulator.output);  // ВЫХОД с регулятора можно подавать напрямую на ШИМ или серво

Тип вычислений

Библиотека имеет режим целочисленных вычислений. Скорость вычислений особо не меняется, но код занимает меньше места и всё-таки должен выполняться быстрее. По умолчанию стоит режим чисел с плавающей точкой, в заголовочном файле библиотеки смотрите ключевое слово datatype, datatype будет float или int в зависимости от настройки: это некоторые переменные и функции. Настройка осуществляется дефайном перед подключением библиотеки:

#define PID_INTEGER
#include "GyverPID.h"

Как работать с библиотекой?

Нужно скормить регулятору текущее значение величины в input, нужное значение в setpoint, провести расчёт при помощи getResult() или getResultTimer(), и после этого выходную величину output подать на управляющее устройство. Делать это нужно часто для быстрых процессов (стабилизация частоты оборотов шпинделя станка под нагрузкой: dt берём около 10-50 мс), и не очень часто для медленных процессов (удержание заданной температуры бойлера: dt можно взять пару секунд, процесс очень инерционный). Функция getResult() делает расчёт в каждый свой вызов и возвращает output, а getResultTimer() делает расчёт только при срабатывании встроенного таймера. То есть getResult() нужно вызывать по своему таймеру (для продвинутых пользователей), а getResultTimer() нужно вызывать как можно чаще, он посчитает только тогда, когда это будет нужно по своему таймеру. После расчёта можно подавать управляющий сигнал (выходную величину output) на управляющее устройство. Смотрите пример!

Как настроить коэффициенты?

Подбор коэффициентов ПИД регулятора – индивидуальная задача, зависящая от конкретных условий и “железа”. Можно почитать статьи на эту тему: например эту, вот эту попроще, и вот эту посложнее. Первым делом нужно установить dt – об этом я писал выше. Маленький dt для быстрых процессов и побольше для медленных (инертных). Dt влияет на расчёты при неизменных коэффициентах, поэтому dt лучше не менять во время настройки, чтобы не пришлось пересчитывать все остальные коэффициенты. Диапазон коэффициентов: 0.01 – 100, т.е. довольно широк и зависит напрямую от инертности системы и выбранного времени dt. Коэффициенты должны быть положительные, противоположное направление регулирования задаётся в setDirection().

В версии 3.0 появился автоматический тюнер коэффициентов, читай ниже.

Оптимизация интегральной суммы (экспериментально)


В реальной системе интегральная сумма может перенасыщаться и стать причиной неадекватного поведения регулятора, “заклинивания” его в крайних положениях. Библиотека предлагает несколько автоматических способов оптимизации интегральной суммы, остальную теорию можно почитать здесь.

С версии 3.1 в библиотеке работает автоматическое ограничение интегральной суммы по выходным лимитам регулятора.

Ручная оптимизация

В версии 2.1 интегральная сумма вынесена в публичный доступ как член класса, к ней можно обратиться как regulator.integral (где regulator – ваше имя объекта). Интегральная составляющая суммирует ошибку по времени, и при слишком сильном накоплении может приводить к перерегулированию (например для инерционных систем, таких как обогреватель). Для наблюдения за её состоянием можно прочитать integral, и при необходимости, например, ограничить её диапазон (regulator.integral = constrain(regulator.integral, -500, 500); каждый раз после вызова getResult()) или даже обнулить (regulator.integral = 0;) по условию.

Режим интегрального окна

В версии 2.3 появился режим интегрального окна, как один из вариантов оптимизации интегральной суммы, может быть полезен для некоторых систем. В этом режиме интегральная сумма складывается из последних N измерений, где N задаётся при помощи дефайна PID_INTEGRAL_WINDOW. Для использования этого режима нужно прописать в скетче дефайн с указанием размера окна до подключения библиотеки.

#define PID_INTEGRAL_WINDOW 50
#include "GyverPID.h"
// ....

Будьте внимательны, внутри библиотеки будет создан массив указанного размера и займёт память! Используйте только в том случае, если понимаете как это работает и для чего оно нужно, а также есть возможность наблюдать за графиком и делать выводы!

Режим оптимизации интегральной суммы

В версии 3.0 появился новый режим автоматической оптимизации интегральной суммы: она автоматически ограничивается так, чтобы выходной сигнал не превышал установленные в setLimits() пределы, то есть инт. сумма не будет бесконечно расти или уменьшаться. В то же время резкие скачки значения с датчика (вход регулятора) вблизи пределов могут приводить к обнулению интегральной суммы, поэтому входной сигнал рекомендуется фильтровать. Для активации режима оптимизации интегральной суммы нужно прописать в скетче дефайн #define PID_OPTIMIZED_I до подключения библиотеки.

Режим “пропорционально скорости”

Выше была описана смена режима работы при помощи setMode(mode);, в режиме ON_RATE регулятор лучше справляется с интегрирующими процессами (например позиция вала мотора), но иногда хорошо работает и с нагревателями, уменьшая переполнение интегральной суммы и перерегулирование в целом. В этом режиме коэффициенты ведут себя иначе и их оптимальные значения отличаются от обычного режима, логика ручной настройки также отличается: коэффициент Kp теперь работает только в паре с Ki и настраивать их нужно вместе, причём в некоторых процессах Kp не даёт никакого эффекта при нулевом Ki, либо работает неадекватно. Смотри пример simulation_linear, в котором симулируется идеальный интегрирующий процесс.

Реализация режима взята отсюда, там же есть теоретическое обоснование.

Тюнер тип 1


Автоматический калибровщик коэффициентов ПИД регулятора, метод “реле” http://auto-controls.blogspot.com/2009/10/pid-controllers-auto-tuning-relay.html. Данный тюнер лучше настраивает коэффициенты для удержания величины и парирования внешних возмущений.

Примечание: тюнер позволяет найти более-менее приемлемые коэффициенты, при которых система будет работать. Эти коэффициенты не являются идеальными и их всё равно придётся покрутить вручную.

Примечание: тюнер выдаёт коэффициенты для ПИ и ПИД регулятора. ПИ регулятор подразумевает, что коэффициент Д будет равен 0.

Как это работает?


  1. Тюнер подаёт управляющий сигнал и ждёт стабилизации значения с датчика
  2. Тюнер изменяет сигнал на некоторую величину (ступеньку)
  3. Ждёт заданное время, затем меняет сигнал на ту же ступеньку, но в другую сторону
  4. Начинается раскачка системы: при прохождении значения с датчика через значение стабилизации сигнал снова переключается
  5. Производится анализ периода раскачки и её амплитуды, на основании этих данных вычисляются рекомендуемые коэффициенты

Как пользоваться библиотекой?


1. Инициализация и настройка

PIDtuner tuner;

tuner.setParameters(направление, сигнал, ступенька, период, точность стабилизации, продолж. импульса, период итерации);

  1. Направление:
    NORMAL: увеличение выходного сигнала увеличивает сигнал с датчика (например обогреватель, мотор)
    REVERSE: увеличение выходного сигнала уменьшает сигнал с датчика (например холодильник, тормоз)
  2. Cигнал: базовый сигнал на управляющее устройство. Система будет ждать стабилизации по величине этого сигнала, и от него будет откладываться ступенька
  3. Ступенька: величина, на которую будет изменяться сигнал в обе стороны от базового
  4. Период: период опроса в ожидании стабилизации
  5. Точность стабилизации: скорость изменения значения с датчика, ниже которой система будет считаться стабильной
  6. Продолж. импульса: время в миллисекундах на первую раскачку
  7. Период итерации: dt системы в мс, желательно должно совпадать с периодом ПИД регулятора

Пример: tuner.setParameters(NORMAL, 130, 40, 2000, 1, 2000, 30);

Калибруем нормальный процесс (увеличение сигнала увеличивает значение с датчика), базовый сигнал 130, ступенька 40 (в процессе калибровки сигнал будет меняться от 130-40 до 130+40, сразу думаем о том, чтобы это не превысило допустимый максимум), на этапе стабилизации хотим, чтобы система считалась стабильной при изменении сигнала с датчика менее, чем на 1 (условная величина датчика) за 2000 миллисекунд. На этапе первоначальной раскачки мы задали длину импульса 2000 мс, период работы всей системы – 30 мс.

2. Структура цикла
Библиотека сделана универсальной для любого датчика и управляющего устройства, цикл тюнинга организуется вот так:

// цикл
tuner.setInput(значение с датчика); // передаём текущее значение с датчика. ЖЕЛАТЕЛЬНО ФИЛЬТРОВАННОЕ
tuner.compute(); // тут производятся вычисления по своему таймеру
// tuner.getOutput(); // тут можно забрать новый управляющий сигнал
analogWrite(pin, tuner.getOutput()); // например для ШИМ

3. Отладка и получение значений
3.1 Во время работы тюнера можно вызвать tuner.getAccuracy() – чем ближе его значение к 100, тем стабильнее на данный момент качается система и
тем вычисляемые коэффициенты будут более близки к идеальным
3.2 Для наблюдения за тюнером через Serial есть готовые методы:
tuner.debugText() выводит текстовые данные (смотри скриншот в папке docs библиотеки)
tuner.debugPlot() выводит данные для построения графика через плоттер Arduino IDE (смотри скриншот в папке docs библиотеки)
3.3 Чтобы получить коэффициенты внутри программы (без Serial) желательно задать условие if (tuner.getAccuracy() > 95) и при наступлении этого условия получить коэффициенты:

tuner.getPI_p() - p для ПИ регулятора
tuner.getPI_i() - i для ПИ регулятора

tuner.getPID_p() - p для ПИД регулятора
tuner.getPID_i() - i для ПИД регулятора
tuner.getPID_d() - d для ПИД регулятора

Смотрите примеры в examples/autotune

Тюнер тип 2


Автоматический калибровщик коэффициентов ПИД регулятора, метод Cohen-Coon https://pages.mtu.edu/~tbco/cm416/cctune.html. Данный тюнер лучше настраивает коэффициенты для переходного процесса, например разогрев с одной температуры до другой.

Примечание: тюнер позволяет найти более-менее приемлемые коэффициенты, при которых система будет работать. Эти коэффициенты не являются идеальными и их всё равно придётся покрутить вручную.

Примечание: тюнер выдаёт коэффициенты для ПИ и ПИД регулятора. ПИ регулятор подразумевает, что коэффициент Д будет равен 0.

Как это работает?


  1. Тюнер подаёт стартовый управляющий сигнал и ждёт стабилизации значения с датчика
  2. Тюнер запоминает минимальное значение и подаёт конечный сигнал, ждёт стабилизации
  3. Тюнер запоминает максимальное значение, снова подаёт начальный сигнал и ждёт стабилизации
  4. Тюнер снова подаёт конечный сигнал
  5. Зная полное время процесса, тюнер измеряет сигнал в определённых точках и по специальным формулам считает коэффициенты

Как пользоваться библиотекой?


1. Инициализация и настройка

PIDtuner2 tuner;

tuner.setParameters(направление, начальный сигнал, конечный сигнал, период, точность, время стабилизации, период итерации)

  1. Направление:
    NORMAL: увеличение выходного сигнала увеличивает сигнал с датчика (например обогреватель, мотор)
    REVERSE: увеличение выходного сигнала уменьшает сигнал с датчика (например холодильник, тормоз)
  2. Начальный сигнал: стартовый сигнал на управляющее устройство
  3. Конечный сигнал: конечный сигнал на управляющее устройство
  4. Период: период опроса в ожидании стабилизации
  5. Точность стабилизации: скорость изменения значения с датчика, ниже которой система будет считаться стабильной
  6. Период итерации: dt системы в мс, желательно должно совпадать с периодом ПИД регулятора

Пример: tuner.setParameters(NORMAL, 150, 200, 1000, 1, 50);

Калибруем нормальный процесс (увеличение сигнала увеличивает значение с датчика), начальный сигнал 150, конечный 200, на этапе стабилизации хотим, чтобы система считалась стабильной при изменении сигнала с датчика менее, чем на 1 (условная величина датчика) за 1000 миллисекунд. Период работы всей системы – 50 мс.

2. Структура цикла
Библиотека сделана универсальной для любого датчика и управляющего устройства, цикл тюнинга организуется вот так:

// цикл
tuner.setInput(значение с датчика); // передаём текущее значение с датчика. ЖЕЛАТЕЛЬНО ФИЛЬТРОВАННОЕ
tuner.compute(); // тут производятся вычисления по своему таймеру
// tuner.getOutput(); // тут можно забрать новый управляющий сигнал
analogWrite(pin, tuner.getOutput()); // например для ШИМ

3. Отладка и получение значений
3.1 Во время работы тюнера можно вызвать tuner.getState() – вернёт номер текущего этапа работы. На 7-ом этапе можно забирать коэффициенты
3.2 Для наблюдения за тюнером через Serial есть готовые методы:
tuner.debugText() выводит текстовые данные (смотри скриншот в папке docs библиотеки)
tuner.debugPlot() выводит данные для построения графика через плоттер Arduino IDE (смотри скриншот в папке docs библиотеки)
3.3 Чтобы получить коэффициенты внутри программы (без Serial) желательно задать условие if (tuner.getState() == 7) и при наступлении этого условия получить коэффициенты:

tuner.getPI_p() - p для ПИ регулятора
tuner.getPI_i() - i для ПИ регулятора

tuner.getPID_p() - p для ПИД регулятора
tuner.getPID_i() - i для ПИД регулятора
tuner.getPID_d() - d для ПИД регулятора

Смотрите примеры в examples/autotune2

// ==== datatype это float или int, в зависимости от выбранного (см. пример integer_calc) ====
GyverPID();
GyverPID(float new_kp, float new_ki, float new_kd, int16_t new_dt = 100);   // kp, ki, kd, dt
	
datatype setpoint = 0;     // заданная величина, которую должен поддерживать регулятор
datatype input = 0;        // сигнал с датчика (например температура, которую мы регулируем)
datatype output = 0;       // выход с регулятора на управляющее устройство (например величина ШИМ или угол поворота серво)
	
datatype getResult();      // возвращает новое значение при вызове (если используем свой таймер с периодом dt!)
datatype getResultTimer(); // возвращает новое значение не ранее, чем через dt миллисекунд (встроенный таймер с периодом dt)

void setDirection(boolean direction);    // направление регулирования: NORMAL (0) или REVERSE (1)
void setMode(boolean mode);              // режим: работа по входной ошибке ON_ERROR (0) или по изменению ON_RATE (1)
void setLimits(int min_output, int max_output);    // лимит выходной величины (например для ШИМ ставим 0-255)
void setDt(int16_t new_dt);              // установка времени дискретизации (для getResultTimer)

float Kp = 0.0;
float Ki = 0.0;
float Kd = 0.0;

ПРИМЕРЫ


/*
   Пример работы ПИД регулятора в автоматическом режиме по встроенному таймеру
   Давайте представим, что на 3 пине у нас спираль нагрева, подключенная через мосфет,
   управляем ШИМ сигналом
   И есть какой то абстрактный датчик температуры, на который влияет спираль
*/
#include "GyverPID.h"

GyverPID regulator(0.1, 0.05, 0.01, 10);  // коэф. П, коэф. И, коэф. Д, период дискретизации dt (мс)
// или так:
// GyverPID regulator(0.1, 0.05, 0.01);	// можно П, И, Д, без dt, dt будет по умолч. 100 мс

void setup() {
  regulator.setDirection(NORMAL); // направление регулирования (NORMAL/REVERSE). ПО УМОЛЧАНИЮ СТОИТ NORMAL
  regulator.setLimits(0, 255);    // пределы (ставим для 8 битного ШИМ). ПО УМОЛЧАНИЮ СТОЯТ 0 И 255
  regulator.setpoint = 50;        // сообщаем регулятору температуру, которую он должен поддерживать

  // в процессе работы можно менять коэффициенты
  regulator.Kp = 5.2;
  regulator.Ki += 0.5;
  regulator.Kd = 0;
}

void loop() {
  int temp;                 // читаем с датчика температуру
  regulator.input = temp;   // сообщаем регулятору текущую температуру

  // getResultTimer возвращает значение для управляющего устройства
  // (после вызова можно получать это значение как regulator.output)
  // обновление происходит по встроенному таймеру на millis()
  analogWrite(3, regulator.getResultTimer());  // отправляем на мосфет

  // .getResultTimer() по сути возвращает regulator.output
}

УСТАНОВКА БИБЛИОТЕКИ

Если вы не знаете, как установить библиотеку – читайте отдельный урок по работе с библиотеками!

БАГИ И ОШИБКИ

Если вы нашли баг или ошибку в исходнике или примерах, или у вас есть идеи по доработке библиотеки – пишите пожалуйста на почту alex@alexgyver.ru. В комментарии на страницах я заглядываю очень редко, на форум – ещё реже.

ОСТАЛЬНЫЕ БИБЛИОТЕКИ

У меня есть ещё очень много всего интересного! Смотрите полный список библиотек вот здесь.