RGB светодиоды и ленты

Немного теории

Я думаю все знают, что свет - это поток фотонов, но в то же время он является электромагнитной волной, излучением. Человеческий глаз воспринимает очень узкий диапазон этого излучения: приблизительно от 390 до 790 ТГц (террагерц), так называемое видимое излучение или видимый свет. "Ориентироваться" в этом диапазоне электромагнитного излучения принято в обратной величине - длине волны, измеряемой в данном случае в нанометрах (нм): человеческий глаз видит излучение в диапазоне от ~400 нм (фиолетовый) до ~800 нм (красный). Между синим и красным есть ещё один важный цвет - зелёный:   Красный (Red, R), зелёный (Green, G) и синий (Blue, B) являются основными цветами: смешивая эти три цвета в разных пропорциях можно получить плюс-минус все остальные цвета.   Этот наглядный "двухмерный" случай с кругами вы тоже скорее всего видели. Если раскручивать тему дальше, то можно задаться интенсивностью каждого цвета и получить итоговый цвет как функцию от трёх переменных, или же трёхмерное цветовое пространство RGB. Если интенсивности всех трёх цветов равны нулю - получится чёрный цвет, если все три максимальны - белый, а всё что между - оттенки:   На картинке выше интенсивность каждого цвета представлена диапазоном 0-255. Знакомое число, не правда ли? Всё верно, в большинстве применений диапазон каждого цвета кодируется одним байтом, потому что это удобно с точки зрения программирования и достаточно с точки зрения глаза: три цвета - три байта - 256*256*256 == 16.8 миллионов оттенков. Да, именно эта цифра часто фигурирует в рекламах смартфонов и телевизоров, и именно столько оттенков мы можем абсолютно не напрягаясь получить при использовании Arduino и RGB светодиодов, о чём и поговорим в этом уроке.

RGB светодиоды

RGB светодиод представляет собой по сути три светодиода в одном корпусе. Чтобы не плодить лишние выводы, все аноды или катоды светодиодов объединяются и получается 4 контакта: R, G, B и общий. Общим может быть как минус-катод (Common Cathode), так и плюс-анод (Common Anode):   Также на этой картинке показана распиновка типичного RGB светодиода: самая длинная нога - общий вывод, крайняя рядом с ней - красный, с другой стороны зелёный дальняя крайняя - синий. К Arduino такой светодиод подключается точно так же, как если бы мы подключали три отдельных светодиода (читай предыдущий урок про светодиоды): на каждый цвет нужен токоограничивающий резистор, а общую ногу нужно подключать в зависимости от того, анод она или катод.   Можно управлять каждым цветом точно так же, как если бы это были отдельные светодиоды. Также не забываем про подключение: если у светодиода общий катод, то высокий сигнал (digitalWrite(pin, HIGH);) с управляющих пинов будет включать выбранный цвет, а если общий анод - то выключать. Соответственно плавное управление яркостью при помощи ШИМ работает по той же логике: у общего катода analogWrite(pin, 200); включит цвет почти на полную яркость, а у общего анода - почти полностью погасит. RGB светодиоды можно дёшево найти на Aliexpress, а именно:

В качестве магазина рекомендую CHANZON, самые хорошие светодиоды и чипы/матрицы.

RGB ленты

RGB светодиодные ленты устроены аналогично одноцветным лентам и RGB светодиодам: в 12 Вольтовой ленте светодиоды каждого цвета соединяются по три штуки с токоограничивающим резистором и образуют сегмент ленты, далее эти сегменты подключаются параллельно.     Также лента имеет общий вывод со всех цветов, в большинстве случаев это общий анод. Почему? Помните, в уроке про управление нагрузкой я говорил, что чаще всего используют N-канальные полевые транзисторы, потому что они дешевле, удобнее в применении и имеют более удачные характеристики? Вот именно поэтому! Драйверы для RGB лент также делают на основе N-канальников, поэтому найти в продаже ленту с общим катодом даже вряд-ли получится. В качестве магазина на aliexpress рекомендую BTF Lighting, самые качественные ленты. Итак, как нам подключить RGB светодиодную ленту к Arduino? Точно так же, как обычную! Но тут я добавлю ещё несколько интересных вариантов.

MOSFET

Нам понадобятся три полевых транзистора и резисторы им в обвязку (почему и зачем - читай в уроке про управление нагрузкой). Подключается всё вот по такой схеме:   Если нужно плавное управление яркостью цветов - подключаем к ШИМ пинам, если просто вкл/выкл - можно к обычным. Свой драйвер на плате можно развести примерно вот так (корпуса D-pak):

LED Amplifier

У китайцев есть готовые драйверы для "усиления" сигнала на RGB ленту, по сути те же три транзистора что выше, но всё красивое и готовое. Подключается следующим образом:

Драйвер Н-моста

Ну и экзотический вариант: использовать полномостовой драйвер для моторов. Почему нет? Количество выходов у таких драйверов всегда кратно двум (для подключения одного мотора), так что это отличный вариант для управления также RGBW лентой. Драйверы можно найти на aliexpress по названию.

Программирование

Программирование эффектов для управления RGB цветом заключается в изменении интенсивностей трёх цветов, то есть трёх численных значений. У меня есть мощная библиотека для RGB светодиодов и лент, в ней реализовано очень много различных удобных инструментов для работы с цветом.

Библиотека GRGB

Полную документацию смотри на GitHub

  • Поддержка драйверов с общим анодом и общим катодом
  • Настройка яркости
  • Гамма-коррекция яркости (квадратный CRT)
  • Библиотека может не привязываться к пинам и просто генерировать значения 8 бит
  • Быстрые оптимизированные целочисленные вычисления (не везде)
  • Плавный переход между любыми цветами (не блокирует выполнение кода)
  • Установка цвета разными способами:
    • RGB
    • HSV
    • Быстрый HSV
    • Цветовое колесо (1530 значений)
    • Цветовое колесо (255 значений)
    • Теплота (1000-40000К)
    • HEX цвета 24 бита
    • HEX цвета 16 бит
    • 17 предустановленных цветов

Например плавная смена цвета по спектру будет выглядеть вот так:

#include "GRGB.h"
GRGB led(COMMON_CATHODE, 6, 5, 3);  // куда подключены цвета (R, G, B)

void setup() {  
}

void loop() {
  byte H = analogRead(0) / 4; // получаем 0-255
  // меняем цвет от 0 до 255
  led.setWheel8(H);
}

В рамках этого урока мы рассмотрим некоторые алгоритмы, потому что это интересно и может пригодиться где-то ещё.

Хранение цвета

Что касается хранения цветовой информации, то это могут быть как три отдельных байта byte r, g, b; , так и более крупный тип данных, например так: long color;. Во втором случае цвет принято записывать в HEX представлении: красный, зелёный и синий байты идут друг за другом 0xRRGGBB. Напомню, что один байт в 16-ричном представлении может иметь значение от 0x00 (0) до 0xFF (255). Таким образом например цвет 0xBBA000 - жёлтый средней яркости (0xBB красный, 0xA0 зелёный, 0x0 синий). Такое представление чаще всего встречается в веб-разработке, при работе с микроконтроллером удобнее хранить цвет в байтах. Вот так можно конвертировать цвет из HEX в байты и наоборот:

// например цвет в HEX
long val = 0x12ff34, val2;
byte r, g, b;
// разбиваем val на байты по цветам RRGGBB
r = (val >> 16) & 0xFF;
g = (val >> 8) & 0xFF;
b = val & 0xFF;


// склеиваем обратно в long
val2 = ((long)r << 16) | ((long)g << 8) | b;
// тут val2 == 0x12ff34

Может пригодиться при связке Arduino и веба.

Включение цветов

Как я уже писал выше, включение того или иного цвета производится точно так же, как в уроке про обычные светодиоды. Для плавного управления яркостью используется ШИМ сигнал.

#define R_PIN 3
#define G_PIN 5
#define B_PIN 6

void setup() {
  pinMode(R_PIN, OUTPUT);
  pinMode(G_PIN, OUTPUT);
  pinMode(B_PIN, OUTPUT);

  // работаем с общим анодом
  // цвет бирюзовый не на всю яркость
  analogWrite(R_PIN, 255);
  analogWrite(G_PIN, 10);
  analogWrite(B_PIN, 10);
}

void loop() {
}

Для плавного управления цветом можно использовать потенциометры:

#define R_PIN 3
#define G_PIN 5
#define B_PIN 6

void setup() {
  pinMode(R_PIN, OUTPUT);
  pinMode(G_PIN, OUTPUT);
  pinMode(B_PIN, OUTPUT);
}

// потенциометры на A0, A1 и A2
void loop() {
  analogWrite(R_PIN, 255 - analogRead(0));
  analogWrite(G_PIN, 255 - analogRead(1));
  analogWrite(B_PIN, 255 - analogRead(2));
}

Цветовое колесо

Первый очевидный эффект - плавное перетекание одного цвета в другой. Это можно сделать линейно, вот таким образом:   Реализовать это можно просто через условия. Продолжим предыдущий пример:

#define R_PIN 3
#define G_PIN 5
#define B_PIN 6

void setup() {
  pinMode(R_PIN, OUTPUT);
  pinMode(G_PIN, OUTPUT);
  pinMode(B_PIN, OUTPUT);
}

void loop() {
  // плавно проходимся по всем цветам
  static int counter = 0;
  counter += 10;
  colorWheel(counter);
  delay(100);
}

// включает цвет по цветовому колесу, принимает 0-1530
void colorWheel(int color) {
  byte _r, _g, _b;
  if (color <= 255) {                       // красный макс, зелёный растёт
    _r = 255;
    _g = color;
    _b = 0;
  }
  else if (color > 255 && color <= 510) {   // зелёный макс, падает красный
    _r = 510 - color;
    _g = 255;
    _b = 0;
  }
  else if (color > 510 && color <= 765) {   // зелёный макс, растёт синий
    _r = 0;
    _g = 255;
    _b = color - 510;
  }
  else if (color > 765 && color <= 1020) {  // синий макс, падает зелёный
    _r = 0;
    _g = 1020 - color;
    _b = 255;
  }
  else if (color > 1020 && color <= 1275) {   // синий макс, растёт красный
    _r = color - 1020;
    _g = 0;
    _b = 255;
  }
  else if (color > 1275 && color <= 1530) { // красный макс, падает синий
    _r = 255;
    _g = 0;
    _b = 1530 - color;
  }
  analogWrite(R_PIN, 255 - _r);
  analogWrite(G_PIN, 255 - _g);
  analogWrite(B_PIN, 255 - _b);
}

Пространство HSV

Следующий вариант более интересен тем, что помимо цвета позволяет настроить его яркость и насыщенность. Такая цветовая модель называется HSV - (Hue, Saturation, Value), или (Цвет, Насыщенность, Яркость), в этом цветовом пространстве гораздо удобнее выбирать нужный цвет. Представить его можно цилиндром:   Светодиод и лента работают в пространстве RGB, HSV цвет нужно конвертировать в RGB для включения соответствующих каналов цвета. В подробности работы алгоритма вдаваться не будем, тем более что существует много разных вариантов его реализации, можно найти их в интернете по запросу HSV to RGB C++. Вот один из них, который использую я:

#define R_PIN 3
#define G_PIN 5
#define B_PIN 6

void setup() {
  pinMode(R_PIN, OUTPUT);
  pinMode(G_PIN, OUTPUT);
  pinMode(B_PIN, OUTPUT);

  // включит красно-жёлтый 
  // с насыщенностью 200 из 255
  // и максимальной яркостью
  setHSV(20, 200, 255);
}

void loop() {
}

// включить цвет в HSV, принимает 0-255 по всем параметрам
void setHSV(uint8_t h, uint8_t s, uint8_t v) {
  float r, g, b;
  byte _r, _g, _b;

  float H = (float)h / 255;
  float S = (float)s / 255;
  float V = (float)v / 255;

  int i = int(H * 6);
  float f = H * 6 - i;
  float p = V * (1 - S);
  float q = V * (1 - f * S);
  float t = V * (1 - (1 - f) * S);

  switch (i % 6) {
    case 0: r = V, g = t, b = p; break;
    case 1: r = q, g = V, b = p; break;
    case 2: r = p, g = V, b = t; break;
    case 3: r = p, g = q, b = V; break;
    case 4: r = t, g = p, b = V; break;
    case 5: r = V, g = p, b = q; break;
  }
  _r = r * 255;
  _g = g * 255;
  _b = b * 255;

  // инверсия для общего анода
  analogWrite(R_PIN, 255 - _r);
  analogWrite(G_PIN, 255 - _g);
  analogWrite(B_PIN, 255 - _b);
}

На этом этапе я могу вам сказать, что после прочтения всех предыдущих уроков вы можете самостоятельно открыть и изучить исходник библиотеки и при желании взять оттуда нужный алгоритм или эффект!

Подключение большого количества RGB

У меня на сайте есть статья, где рассказано об алгоритме динамической индикации RGB светодиодов. Она позволяет подключить несколько RGB светодиодов или лент с возможностью изменения цвета.

 

Полезные страницы

1 1 голос
Рейтинг статьи
Обновлено
Подписаться
Уведомить о
guest

14 комментариев
Старые
Новые Популярные
Межтекстовые Отзывы
Посмотреть все комментарии
Прокрутить вверх